// ----------------------------------------------------
   // Method: PICT_IsLegacyPICT
   // ----------------------------------------------------

C_PICTURE($1;$pict)// Picture to test
C_BOOLEAN($0;$isMacPict)// True if legacy PICT

$pict:=$1
$isMacPict:=False

C_LONGINT($err;$quality;$depth)
C_TEXT($codec)

$err:=QPx_GetCompressedPictureInfo ($pict;$codec;$quality;$depth)
If ($err=0)
   
      // We are using regex for case-sensitive string matching
   
   Case of 
         
            // QT compressed PICTs: codec types are lower-case 4-char codes
      : (Match regex("^[a-z0-9 ]{4}$";$codec))
         
         $isMacPict:=True
         
            // Uncompressed Mac PICT
      : (Match regex("^PICT$";$codec))
         
         $isMacPict:=True
         
   End case 
   
End if 

$0:=$isMacPict



   // ----------------------------------------------------
   // Method: PICT_Upgrade
   // ----------------------------------------------------

C_POINTER($1;$pictPtr)// Pointer to picture
C_TEXT($2;$prefCodec)// Preferred codec for pictures that need to be re-encoded.
   // Optional, defaults to jpeg.
C_LONGINT($3;$prefQuality)// Preferred compression quality for pictures that need to be re-encoded.
   // Optional, defaults to qpx_NormalQuality.
C_LONGINT($0;$result)
   // 0: no upgrade was necessary
   // 1: picture converted directly
   // 2: picture re-encoded
   // <0: error

$pictPtr:=$1
If (Count parameters>1)
   $prefCodec:=$2
Else 
   $prefCodec:="jpeg"
End if 
If (Count parameters>2)
   $prefQuality:=$3
Else 
   $prefQuality:=qpx_NormalQuality
End if 
$result:=0

C_PICTURE($pict)
$pict:=$pictPtr->

C_LONGINT($err;$quality;$depth)
C_TEXT($codec)
C_BLOB($data)

$result:=QPx_GetCompressedPictureInfo ($pict;$codec;$quality;$depth;$data)
If ($result=0)
   
      // We are using regex for case-sensitive string matching
   
   If (Match regex("^(jpeg|png )$";$codec))
         // QT codecs that are converted without re-encoding
      
      BLOB TO PICTURE($data;$pict)
      $pictPtr->:=$pict
      
      $result:=1
      
   Else 
      
         // Other Mac picts - either QT-compressed or uncompressed
      If (Match regex("^[a-z0-9 ]{4}$";$codec) | Match regex("^PICT$";$codec))
         
         $result:=QPx_CompressPicture ($pict;$prefCodec;$prefQuality)
         If ($result=0)
            
            $pictPtr->:=$pict
            
            $result:=2
            
         End if 
         
      End if 
      
   End if 
   
End if 

$0:=$result